r733 - in packages: . libtest-pod-coverage-perl libtest-pod-coverage-perl/branches libtest-pod-coverage-perl/branches/upstream libtest-pod-coverage-perl/branches/upstream/current libtest-pod-coverage-perl/branches/upstream/current/t
Allard Hoeve
hoeve-guest@costa.debian.org
Thu, 10 Mar 2005 13:42:17 +0100
Author: hoeve-guest
Date: 2005-03-10 13:42:15 +0100 (Thu, 10 Mar 2005)
New Revision: 733
Added:
packages/libtest-pod-coverage-perl/
packages/libtest-pod-coverage-perl/branches/
packages/libtest-pod-coverage-perl/branches/upstream/
packages/libtest-pod-coverage-perl/branches/upstream/current/
packages/libtest-pod-coverage-perl/branches/upstream/current/Changes
packages/libtest-pod-coverage-perl/branches/upstream/current/Coverage.pm
packages/libtest-pod-coverage-perl/branches/upstream/current/MANIFEST
packages/libtest-pod-coverage-perl/branches/upstream/current/META.yml
packages/libtest-pod-coverage-perl/branches/upstream/current/Makefile.PL
packages/libtest-pod-coverage-perl/branches/upstream/current/t/
packages/libtest-pod-coverage-perl/branches/upstream/current/t/00.load.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nopod.pm
packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nosymbols.pm
packages/libtest-pod-coverage-perl/branches/upstream/current/t/Privates.pm
packages/libtest-pod-coverage-perl/branches/upstream/current/t/Simple.pm
packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_modules.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_pod_coverage_ok.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/nopod.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/nosymbols.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/parms.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/pod.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/privates.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/self.t
packages/libtest-pod-coverage-perl/branches/upstream/current/t/simple.t
packages/libtest-pod-coverage-perl/tags/
Log:
[svn-inject] Installing original source of libtest-pod-coverage-perl
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/Changes
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/Changes 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/Changes 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,48 @@
+Revision history for Test::Pod::Coverage
+
+1.06 Tue Jun 22 16:51:42 CDT 2004
+ [ENHANCEMENTS]
+ * Looks in blib/ if there is one, otherwise looks in lib/
+ * Doesn't report "no public symbols" unless verbose mode is on.
+ * Thanks to David Wheeler and Shawn Sorichetti for nudging.
+ This behavior will be in Test::Pod soon, too.
+
+1.04 Sat May 1 00:06:14 CDT 2004
+ [FIXES]
+ * Now it runs taint-safe. I was not untainting the filename.
+
+1.02 Fri Apr 30 23:27:23 CDT 2004
+ [FIXES]
+ * Fixed a warning in all_modules() under 5.8.3
+
+1.00 Wed Apr 28 23:50:19 CDT 2004
+ [ENHANCEMENTS]
+ * Now runs taint-safe.
+ * No longer uses File::Find.
+
+0.08 Fri Feb 13 23:13:21 CST 2004
+ [ENHANCEMENTS]
+ * Added all_pod_coverage_ok(), and all_modules() for support.
+
+0.06 Jan 27 2004
+ [ENHANCEMENTS]
+ * Files with all pod and no symbols is no longer an error.
+ * Enhanced some of the error messages.
+
+0.04 Sun Jan 18 21:51:59 CST 2004
+ [ENHANCEMENTS]
+ * Now lists the naked subroutines in the error message.
+
+
+0.03 Sat Jan 17 11:14:56 CST 2004
+ [ENHANCEMENTS]
+ * Now says what module has a problem if it can't find any
+ POD. Thanks, Barbie.
+
+ [INTERNALS]
+ * Added a couple more tests to bring my test coverage up
+ to 100%, according to Devel::Cover. Whoo!
+
+0.02
+ First version with the new reasonable API on pod_coverage_ok().
+ If you got in on 0.01, switch now.
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/Coverage.pm
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/Coverage.pm 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/Coverage.pm 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,237 @@
+package Test::Pod::Coverage;
+
+=head1 NAME
+
+Test::Pod::Coverage - Check for pod coverage in your distribution.
+
+=head1 VERSION
+
+Version 1.06
+
+ $Header: /home/cvs/test-pod-coverage/Coverage.pm,v 1.26 2004/06/22 22:02:06 andy Exp $
+
+=cut
+
+our $VERSION = "1.06";
+
+=head1 SYNOPSIS
+
+Checks for POD coverage in files for your distribution.
+
+ use Test::Pod::Coverage tests=>1;
+ pod_coverage_ok( "Foo::Bar", "Foo::Bar is covered" );
+
+Can also be called with L<Pod::Coverage> parms.
+
+ use Test::Pod::Coverage tests=>1;
+ pod_coverage_ok(
+ "Foo::Bar",
+ { also_private => [ qr/^[A-Z_]+$/ ], },
+ "Foo::Bar, with all-caps functions as privates",
+ );
+
+The L<Pod::Coverage> parms are also useful for subclasses that don't
+re-document the parent class's methods. Here's an example from
+L<Mail::SRS>.
+
+ pod_coverage_ok( "Mail::SRS" ); # No exceptions
+
+ # Define the three overridden methods.
+ my $trustme = { trustme => [qr/^(new|parse|compile)$/] };
+ pod_coverage_ok( "Mail::SRS::DB", $trustme );
+ pod_coverage_ok( "Mail::SRS::Guarded", $trustme );
+ pod_coverage_ok( "Mail::SRS::Reversable", $trustme );
+ pod_coverage_ok( "Mail::SRS::Shortcut", $trustme );
+
+If you want POD coverage for your module, but don't want to make
+Test::Pod::Coverage a prerequisite for installing, create the following
+as your F<t/pod-coverage.t> file:
+
+ use Test::More;
+ eval "use Test::Pod::Coverage";
+ plan skip_all => "Test::Pod::Coverage required for testing pod coverage" if $@;
+
+ plan tests => 1;
+ pod_coverage_ok( "Pod::Master::Html");
+
+Finally, Module authors can include the following in a F<t/pod-coverage.t>
+file and have C<Test::Pod::Coverage> automatically find and check all
+modules in the module distribution:
+
+ use Test::More;
+ eval "use Test::Pod::Coverage 1.00";
+ plan skip_all => "Test::Pod::Coverage 1.00 required for testing POD coverage" if $@;
+ all_pod_coverage_ok();
+
+=cut
+
+use strict;
+use warnings;
+
+use Pod::Coverage;
+use Test::Builder;
+
+my $Test = Test::Builder->new;
+
+sub import {
+ my $self = shift;
+ my $caller = caller;
+ no strict 'refs';
+ *{$caller.'::pod_coverage_ok'} = \&pod_coverage_ok;
+ *{$caller.'::all_pod_coverage_ok'} = \&all_pod_coverage_ok;
+
+ $Test->exported_to($caller);
+ $Test->plan(@_);
+}
+
+=head1 FUNCTIONS
+
+=head2 all_pod_coverage_ok( [$parms, ] $msg )
+
+Checks that the POD code in all modules in the distro have proper POD
+coverage.
+
+If the I<$parms> hashref if passed in, they're passed into the
+C<Pod::Coverage> object that the function uses. Check the
+L<Pod::Coverage> manual for what those can be.
+
+=cut
+
+sub all_pod_coverage_ok {
+ my $parms = (@_ && (ref $_[0] eq "HASH")) ? shift : {};
+ my $msg = shift;
+
+ my $ok = 1;
+ my @modules = all_modules();
+ if ( @modules ) {
+ $Test->plan( tests => scalar @modules );
+
+ for my $module ( @modules ) {
+ my $thismsg = defined $msg ? $msg : "Pod coverage on $module";
+
+ my $thisok = pod_coverage_ok( $module, $parms, $thismsg );
+ $ok = 0 unless $thisok;
+ }
+ } else {
+ $Test->plan( tests => 1 );
+ $Test->ok( 1, "No modules found." );
+ }
+
+ return $ok;
+}
+
+
+=head2 pod_coverage_ok( $module, [$parms, ] $msg )
+
+Checks that the POD code in I<$module> has proper POD coverage.
+
+If the I<$parms> hashref if passed in, they're passed into the
+C<Pod::Coverage> object that the function uses. Check the
+L<Pod::Coverage> manual for what those can be.
+
+=cut
+
+sub pod_coverage_ok {
+ my $module = shift;
+ my $parms = (@_ && (ref $_[0] eq "HASH")) ? shift : {};
+ my $msg = @_ ? shift : "Pod coverage on $module";
+
+ my $pc = Pod::Coverage->new( package => $module, %$parms );
+ my $rating = $pc->coverage;
+ my $ok;
+ if ( defined $rating ) {
+ $ok = ($rating == 1);
+ $Test->ok( $ok, $msg );
+ if ( !$ok ) {
+ my @nakies = sort $pc->naked;
+ my $s = @nakies == 1 ? "" : "s";
+ $Test->diag(
+ sprintf( "Coverage for %s is %3.1f%%, with %d naked subroutine$s:",
+ $module, $rating*100, scalar @nakies ) );
+ $Test->diag( "\t$_" ) for @nakies;
+ }
+ } else { # No symbols
+ my $why = $pc->why_unrated;
+ my $nopublics = ( $why =~ "no public symbols defined" );
+ my $verbose = $ENV{HARNESS_VERBOSE} || 0;
+ $ok = $nopublics;
+ $Test->ok( $ok, $msg );
+ $Test->diag( "$module: $why" ) unless ( $nopublics && !$verbose );
+ }
+
+ return $ok;
+}
+
+=head2 all_modules( [@dirs] )
+
+Returns a list of all modules in I<$dir> and in directories below. If
+no directories are passed, it defaults to "blib".
+
+Note that the modules are as "Foo::Bar", not "Foo/Bar.pm".
+
+The order of the files returned is machine-dependent. If you want them
+sorted, you'll have to sort them yourself.
+
+=cut
+
+sub all_modules {
+ my @starters = @_ ? @_ : _starting_points();
+ my %starters = map {$_,1} @starters;
+
+ my @queue = @starters;
+
+ my @modules;
+ while ( @queue ) {
+ my $file = shift @queue;
+ if ( -d $file ) {
+ local *DH;
+ opendir DH, $file or next;
+ my @newfiles = readdir DH;
+ closedir DH;
+
+ @newfiles = File::Spec->no_upwards( @newfiles );
+ @newfiles = grep { $_ ne "CVS" && $_ ne ".svn" } @newfiles;
+
+ push @queue, map "$file/$_", @newfiles;
+ }
+ if ( -f $file ) {
+ next unless $file =~ /\.pm$/;
+
+ my @parts = File::Spec->splitdir( $file );
+ shift @parts if @parts && exists $starters{$parts[0]};
+ shift @parts if @parts && $parts[0] eq "lib";
+ $parts[-1] =~ s/\.pm$// if @parts;
+
+ # Untaint the parts
+ for ( @parts ) {
+ /^([a-zA-Z0-9_]+)$/;
+ die qq{Invalid and untaintable filename "$file"!} unless $_ eq $1;
+ $_ = $1;
+ }
+ my $module = join( "::", @parts );
+ push( @modules, $module );
+ }
+ } # while
+
+ return @modules;
+}
+
+sub _starting_points {
+ return 'blib' if -e 'blib';
+ return 'lib';
+}
+
+=head1 AUTHOR
+
+Written by Andy Lester, C<< <andy@petdance.com> >>.
+
+=head1 COPYRIGHT
+
+Copyright 2004, Andy Lester, All Rights Reserved.
+
+You may use, modify, and distribute this package under the
+same terms as Perl itself.
+
+=cut
+
+1;
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/MANIFEST
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/MANIFEST 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/MANIFEST 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,19 @@
+Changes
+Coverage.pm
+MANIFEST
+META.yml
+Makefile.PL
+t/00.load.t
+t/all_pod_coverage_ok.t
+t/Nopod.pm
+t/Nosymbols.pm
+t/Privates.pm
+t/Simple.pm
+t/all_modules.t
+t/nopod.t
+t/nosymbols.t
+t/parms.t
+t/pod.t
+t/privates.t
+t/self.t
+t/simple.t
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/META.yml
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/META.yml 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/META.yml 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,13 @@
+# http://module-build.sourceforge.net/META-spec.html
+#XXXXXXX This is a prototype!!! It will change in the future!!! XXXXX#
+name: Test-Pod-Coverage
+version: 1.06
+version_from: Coverage.pm
+installdirs: site
+requires:
+ Pod::Coverage: 0
+ Test::Builder::Tester: 0
+ Test::More: 0
+
+distribution_type: module
+generated_by: ExtUtils::MakeMaker version 6.21
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/Makefile.PL
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/Makefile.PL 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/Makefile.PL 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,16 @@
+use strict;
+use warnings;
+use ExtUtils::MakeMaker;
+
+WriteMakefile(
+ NAME => 'Test::Pod::Coverage',
+ VERSION_FROM => 'Coverage.pm',
+ ABSTRACT => "Check for pod coverage in your distribution",
+ PREREQ_PM => {
+ 'Pod::Coverage' => 0,
+ 'Test::More' => 0,
+ 'Test::Builder::Tester' => 0,
+ },
+ dist => { COMPRESS => 'gzip -9f', SUFFIX => 'gz', },
+ clean => { FILES => 'Test-Pod-Coverage-*' },
+);
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/00.load.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/00.load.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/00.load.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,7 @@
+#!perl -T
+
+use Test::More tests => 1;
+
+use_ok( 'Test::Pod::Coverage' );
+
+diag( "Testing Test::Pod::Coverage $Test::Pod::Coverage::VERSION" );
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nopod.pm
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nopod.pm 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nopod.pm 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,9 @@
+package Nopod;
+
+# Documentation is for wimps!
+#
+sub foo {}
+sub bar {}
+sub baz {}
+
+1;
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nosymbols.pm
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nosymbols.pm 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/Nosymbols.pm 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,13 @@
+package Nosymbols;
+
+=head1 NAME
+
+This is a dummy module with all POD, no symbols.
+
+=head1 DESCRIPTION
+
+This is a pod file without errors.
+
+=cut
+
+1;
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/Privates.pm
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/Privates.pm 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/Privates.pm 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,33 @@
+package Privates;
+
+sub foo {}
+sub bar {}
+sub baz {}
+sub INTERNAL_THING {}
+sub INTERNAL_DOODAD {}
+
+1;
+__END__
+
+# test module - three subs, one without, one with an item, one with a head2
+
+=head2 Methods
+
+=over
+
+=item foo
+
+this is foo
+
+=back
+
+=head2 bar
+
+The bar is just a throwaway.
+
+=head2 baz
+
+baz is very important
+
+=cut
+
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/Simple.pm
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/Simple.pm 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/Simple.pm 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,31 @@
+package Simple;
+
+sub foo {}
+sub bar {}
+sub baz {}
+
+1;
+__END__
+
+# test module - three subs, one without, one with an item, one with a head2
+
+=head2 Methods
+
+=over
+
+=item foo
+
+this is foo
+
+=back
+
+=head2 bar
+
+The bar is just a throwaway.
+
+=head2 baz
+
+baz is very important
+
+=cut
+
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_modules.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_modules.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_modules.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,18 @@
+#!perl -T
+
+use strict;
+
+use Test::More tests => 2;
+
+BEGIN {
+ use_ok( "Test::Pod::Coverage" );
+}
+
+my @files = Test::Pod::Coverage::all_modules( "blib" );
+
+# The expected files have slashes, not File::Spec separators, because
+# that's how File::Find does it.
+my @expected = qw( Test::Pod::Coverage );
+@files = sort @files;
+@expected = sort @expected;
+is_deeply( \@files, \@expected, "Got all the distro files" );
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_pod_coverage_ok.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_pod_coverage_ok.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/all_pod_coverage_ok.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,6 @@
+#!perl -T
+
+# This is the most basic form that most people will use.
+
+use Test::Pod::Coverage;
+all_pod_coverage_ok();
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/nopod.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/nopod.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/nopod.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,16 @@
+#!perl -T
+
+use strict;
+use lib "t";
+use Test::More tests=>2;
+use Test::Builder::Tester;
+
+BEGIN {
+ use_ok( 'Test::Pod::Coverage' );
+}
+
+test_out( "not ok 1 - Checking Nopod" );
+test_fail(+2);
+test_diag( "Nopod: couldn't find pod" );
+pod_coverage_ok( "Nopod", "Checking Nopod" );
+test_test( "Handles files with no pod at all" );
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/nosymbols.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/nosymbols.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/nosymbols.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,24 @@
+#!perl -T
+
+use strict;
+use lib "t";
+use Test::More tests => 3;
+use Test::Builder::Tester;
+
+BEGIN {
+ use_ok( 'Test::Pod::Coverage' );
+}
+
+NO_VERBOSE: {
+ test_out( "ok 1 - Checking Nosymbols" );
+ pod_coverage_ok( "Nosymbols", "Checking Nosymbols" );
+ test_test( "Handles files with no symbols" );
+}
+
+VERBOSE: {
+ local $ENV{HARNESS_VERBOSE} = 1;
+ test_out( "ok 1 - Checking Nosymbols" );
+ test_diag( "Nosymbols: no public symbols defined" );
+ pod_coverage_ok( "Nosymbols", "Checking Nosymbols" );
+ test_test( "Handles files with no symbols" );
+}
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/parms.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/parms.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/parms.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,16 @@
+#!perl -T
+
+use lib "t";
+use strict;
+use Test::More tests=>2;
+use Test::Builder::Tester;
+
+BEGIN {
+ use_ok( 'Test::Pod::Coverage' );
+}
+
+OPTIONAL_MESSAGE: {
+ test_out( "ok 1 - Pod coverage on Simple" );
+ pod_coverage_ok( "Simple" );
+ test_test( "Simple runs under T:B:T" );
+}
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/pod.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/pod.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/pod.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,6 @@
+#!perl -T
+
+use Test::More;
+eval "use Test::Pod 1.14";
+plan skip_all => "Test::Pod 1.14 required for testing POD" if $@;
+all_pod_files_ok();
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/privates.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/privates.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/privates.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,37 @@
+#!perl -T
+
+use strict;
+use lib "t";
+use Test::More tests=>4;
+use Test::Builder::Tester;
+
+BEGIN {
+ use_ok( 'Test::Pod::Coverage' );
+}
+
+MISSING_FUNCS: {
+ test_out( "not ok 1 - Privates fails" );
+ test_fail(+4);
+ test_diag( "Coverage for Privates is 60.0%, with 2 naked subroutines:" );
+ test_diag( "\tINTERNAL_DOODAD" );
+ test_diag( "\tINTERNAL_THING" );
+ pod_coverage_ok( "Privates", "Privates fails" );
+ test_test( "Should fail at 60%" );
+}
+
+SPECIFIED_PRIVATES: {
+ test_out( "ok 1 - Privates works w/a custom PC object" );
+ pod_coverage_ok(
+ "Privates",
+ { also_private => [ qr/^[A-Z_]+$/ ], },
+ "Privates works w/a custom PC object"
+ );
+ test_test( "Trying to pass PC object" );
+}
+
+SPECIFIED_PRIVATES_NAKED: {
+ pod_coverage_ok(
+ "Privates",
+ { also_private => [ qr/^[A-Z_]+$/ ], },
+ );
+}
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/self.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/self.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/self.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,7 @@
+#!perl -T
+
+use lib "t";
+use strict;
+use Test::Pod::Coverage tests=>1;
+
+pod_coverage_ok( "Test::Pod::Coverage", "T:P:C itself is OK" );
Added: packages/libtest-pod-coverage-perl/branches/upstream/current/t/simple.t
===================================================================
--- packages/libtest-pod-coverage-perl/branches/upstream/current/t/simple.t 2005-03-10 12:41:03 UTC (rev 732)
+++ packages/libtest-pod-coverage-perl/branches/upstream/current/t/simple.t 2005-03-10 12:42:15 UTC (rev 733)
@@ -0,0 +1,21 @@
+#!perl -T
+
+use lib "t";
+use strict;
+use Test::More tests=>4;
+use Test::Builder::Tester;
+
+BEGIN {
+ use_ok( 'Test::Pod::Coverage' );
+}
+
+pod_coverage_ok( "Simple", "Simple is OK" );
+
+# Now try it under T:B:T
+test_out( "ok 1 - Simple is still OK" );
+pod_coverage_ok( "Simple", "Simple is still OK" );
+test_test( "Simple runs under T:B:T" );
+
+test_out( "ok 1 - Pod coverage on Simple" );
+pod_coverage_ok( "Simple" );
+test_test( "Simple runs under T:B:T" );