r41173 - in /branches/upstream/libhtml-wikiconverter-oddmuse-perl/current: ./ lib/ lib/HTML/ lib/HTML/WikiConverter/ t/

ryan52-guest at users.alioth.debian.org ryan52-guest at users.alioth.debian.org
Mon Aug 3 08:09:55 UTC 2009


Author: ryan52-guest
Date: Mon Aug  3 08:09:50 2009
New Revision: 41173

URL: http://svn.debian.org/wsvn/pkg-perl/?sc=1&rev=41173
Log:
Load /tmp/tmp.eEariZDUXR/to_upload/HTML-WikiConverter-Oddmuse-0.52 into
branches/upstream/libhtml-wikiconverter-oddmuse-perl/current.

Added:
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Changes
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/MANIFEST
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/META.yml
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Makefile.PL
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/README
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/WikiConverter/
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/WikiConverter/Oddmuse.pm
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/00-load.t
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/boilerplate.t
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/oddmuse.t
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod-coverage.t
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod.t
    branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/runtests.pl

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Changes
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Changes?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Changes (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Changes Mon Aug  3 08:09:50 2009
@@ -1,0 +1,18 @@
+# Change log for HTML::WikiConverter::Oddmuse
+
+version: 0.52
+date:    Thu Jul 20 2006
+changes:
+  - add attribute types
+  - require Params::Validate
+  - require HTML::WikiConverter 0.60
+
+version: 0.51
+date:    Fri Jul 7 2006
+changes:
+  - Add support for <h1> through <h6>
+
+version: 0.50
+date:    Tue Jan 10 2006
+changes:
+  - Branched from main HTML::WikiConverter codebase.

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/MANIFEST
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/MANIFEST?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/MANIFEST (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/MANIFEST Mon Aug  3 08:09:50 2009
@@ -1,0 +1,12 @@
+Changes
+MANIFEST
+META.yml # Will be created by "make dist"
+Makefile.PL
+README
+lib/HTML/WikiConverter/Oddmuse.pm
+t/00-load.t
+t/boilerplate.t
+t/oddmuse.t
+t/pod-coverage.t
+t/pod.t
+t/runtests.pl

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/META.yml
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/META.yml?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/META.yml (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/META.yml Mon Aug  3 08:09:50 2009
@@ -1,0 +1,13 @@
+# http://module-build.sourceforge.net/META-spec.html
+#XXXXXXX This is a prototype!!!  It will change in the future!!! XXXXX#
+name:         HTML-WikiConverter-Oddmuse
+version:      0.52
+version_from: lib/HTML/WikiConverter/Oddmuse.pm
+installdirs:  site
+requires:
+    HTML::WikiConverter:           0.6
+    Params::Validate:              0
+    Test::More:                    0
+
+distribution_type: module
+generated_by: ExtUtils::MakeMaker version 6.17

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Makefile.PL
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Makefile.PL?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Makefile.PL (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/Makefile.PL Mon Aug  3 08:09:50 2009
@@ -1,0 +1,18 @@
+use strict;
+use warnings;
+use ExtUtils::MakeMaker;
+
+WriteMakefile(
+    NAME                => 'HTML::WikiConverter::Oddmuse',
+    AUTHOR              => 'David J. Iberri <diberri at cpan.org>',
+    VERSION_FROM        => 'lib/HTML/WikiConverter/Oddmuse.pm',
+    ABSTRACT_FROM       => 'lib/HTML/WikiConverter/Oddmuse.pm',
+    PL_FILES            => {},
+    PREREQ_PM => {
+        'Test::More' => 0,
+        'HTML::WikiConverter' => 0.60,
+        'Params::Validate' => 0,
+    },
+    dist                => { COMPRESS => 'gzip -9f', SUFFIX => 'gz', },
+    clean               => { FILES => 'HTML-WikiConverter-Oddmuse-*' },
+);

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/README
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/README?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/README (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/README Mon Aug  3 08:09:50 2009
@@ -1,0 +1,63 @@
+HTML::WikiConverter::Oddmuse
+============================
+
+HTML::WikiConverter::Oddmuse adds the Oddmuse dialect to
+HTML::WikiConverter allowing the conversion of HTML to Oddmuse markup.
+
+SYNOPSIS
+
+Converting HTML to wiki markup is easy:
+
+  use HTML::WikiConverter;
+  my $wc = new HTML::WikiConverter( dialect => 'Oddmuse' );
+  print $wc->html2wiki( $html );
+
+Or from the command line:
+
+  % html2wiki --dialect Oddmuse input.html > output.wiki
+
+There's also a web interface if you're so inclined:
+
+  http://diberri.dyndns.org/wikipedia/html2wiki/
+
+CHANGES IN 0.52
+
+  * Require HTML::WikiConverter 0.60
+  * Require Params::Validate
+
+INSTALLATION
+
+To install this module, run the following commands:
+
+    perl Makefile.PL
+    make
+    make test
+    make install
+
+SUPPORT AND DOCUMENTATION
+
+After installing, you can find documentation for this module with the
+perldoc command.
+
+    perldoc HTML::WikiConverter::Oddmuse
+
+You can also look for information at:
+
+    Search CPAN
+        http://search.cpan.org/dist/HTML-WikiConverter-Oddmuse
+
+    CPAN Request Tracker:
+        http://rt.cpan.org/NoAuth/Bugs.html?Dist=HTML-WikiConverter-Oddmuse
+
+    AnnoCPAN, annotated CPAN documentation:
+        http://annocpan.org/dist/HTML-WikiConverter-Oddmuse
+
+    CPAN Ratings:
+        http://cpanratings.perl.org/d/HTML-WikiConverter-Oddmuse
+
+COPYRIGHT AND LICENCE
+
+Copyright (C) 2006 David J. Iberri
+
+This program is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/WikiConverter/Oddmuse.pm
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/WikiConverter/Oddmuse.pm?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/WikiConverter/Oddmuse.pm (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/lib/HTML/WikiConverter/Oddmuse.pm Mon Aug  3 08:09:50 2009
@@ -1,0 +1,200 @@
+package HTML::WikiConverter::Oddmuse;
+
+use warnings;
+use strict;
+
+use base 'HTML::WikiConverter';
+
+our $VERSION = '0.52';
+
+use Params::Validate ':types';
+
+=head1 NAME
+
+HTML::WikiConverter::Oddmuse - Convert HTML to Oddmuse markup
+
+=head1 SYNOPSIS
+
+  use HTML::WikiConverter;
+  my $wc = new HTML::WikiConverter( dialect => 'Oddmuse' );
+  print $wc->html2wiki( $html );
+
+=head1 DESCRIPTION
+
+This module contains rules for converting HTML into Oddmuse
+markup. This dialect module supports most of Oddmuse's text formatting
+rules described at [1], notably:
+
+  * bold, strong, italic, emphasized, and underlined text
+  * paragraph blocks
+  * external images
+  * internal and external links
+  * unordered and ordered lists
+  * tables [2]
+
+ [1] http://www.oddmuse.org/cgi-bin/wiki/Text_Formatting_Rules
+ [2] http://www.oddmuse.org/cgi-bin/wiki/Table_Markup_Extension
+
+See L<HTML::WikiConverter> for usage details.
+
+=head1 ATTRIBUTES
+
+In addition to the regular set of attributes recognized by the
+L<HTML::WikiConverter> constructor, this dialect also accepts the
+following attributes:
+
+=head2 camel_case
+
+Boolean indicating whether CamelCase links are enabled in the target
+Oddmuse installation. This corresponds to Oddmuse's C<$WikiLinks>
+configuration parameter. Enabling CamelCase links will turn HTML like
+this:
+
+  <p><a href="/wiki/CamelCase">CamelCase</a> links are fun.</p>
+
+into this Oddmuse markup:
+
+  CamelCase links are fun.
+
+Disabling CamelCase links (the default) would convert that HTML into
+
+  [[CamelCase]] links are fun.
+
+=cut
+
+sub attributes { {
+  camel_case => { default => 0, type => BOOLEAN }
+} }
+
+sub rules {
+  my %rules = (
+    b => { start => '*', end => '*' },
+    strong => { alias => 'b' },
+    i => { start => '/', end => '/' },
+    em => { start => '~', end => '~' },
+    u => { start => '_', end => '_' },
+    
+    p => { block => 1, trim => 'both', line_format => 'multi' },
+    img => { replace => \&_image },
+    a => { replace => \&_link },
+
+    ul => { line_format => 'multi', block => 1 },
+    ol => { alias => 'ul' },
+    li => { start => \&_li_start, trim => 'leading' },
+
+    # http://www.oddmuse.org/cgi-bin/wiki/Table_Markup_Extension
+    table => { block => 1, line_format => 'multi' },
+    tr => { line_format => 'single', end => "||\n" },
+    td => { start => \&_td_start, end => \&_td_end, trim => 'both' },
+    th => { alias => 'td' },
+
+    h1 => { start => '=', end => '=', block => 1, line_format => 'single' },
+    h2 => { start => '==', end => '==', block => 1, line_format => 'single' },
+    h3 => { start => '===', end => '===', block => 1, line_format => 'single' },
+    h4 => { start => '====', end => '====', block => 1, line_format => 'single' },
+    h5 => { start => '=====', end => '=====', block => 1, line_format => 'single' },
+    h6 => { start => '======', end => '======', block => 1, line_format => 'single' },
+  );
+
+  return \%rules;
+}
+
+sub _td_start {
+  my( $self, $node, $rules ) = @_;
+  my $align = $node->attr('align') || 'left';
+  my $colspan = $node->attr('colspan') || 1;
+
+  my $prefix = ( '||' ) x $colspan;
+  my $pad_for_align = $align eq 'left' ? '' : ' ';
+  return $prefix.$pad_for_align;
+}
+
+sub _td_end {
+  my( $self, $node, $rules ) = @_;
+  my $align = $node->attr('align') || 'left';
+  return $align eq 'right' ? '' : ' ';
+}
+
+sub _link {
+  my( $self, $node, $rules ) = @_;
+  my $url = $node->attr('href') || '';
+  my $text = $self->get_elem_contents($node) || '';
+  
+  if( my $title = $self->get_wiki_page($url) ) {
+    $title =~ s/_/ /g;
+    return $text if $self->camel_case and lc $title eq lc $text and $self->is_camel_case($text);
+    return "[[$text]]" if lc $text eq lc $title;
+    return "[[$title|$text]]";
+  } else {
+    return $url if $url eq $text;
+    return "[$url $text]";
+  }
+}
+
+sub _image {
+  my( $self, $node, $rules ) = @_;
+  my $src = $node->attr('src') || '';
+  return '' unless $src;
+
+  # Could do something with an 'image_uri' option to handle local images
+  return $src;
+}
+
+sub _li_start {
+  my( $self, $node, $rules ) = @_;
+  my @parent_lists = $node->look_up( _tag => qr/ul|ol/ );
+  my $prefix = ('*') x @parent_lists;
+  return "\n$prefix ";
+}
+
+=head1 AUTHOR
+
+David J. Iberri, C<< <diberri at cpan.org> >>
+
+=head1 BUGS
+
+Please report any bugs or feature requests to
+C<bug-html-wikiconverter-oddmuse at rt.cpan.org>, or through the web
+interface at
+L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=HTML-WikiConverter-Oddmuse>.
+I will be notified, and then you'll automatically be notified of
+progress on your bug as I make changes.
+
+=head1 SUPPORT
+
+You can find documentation for this module with the perldoc command.
+
+    perldoc HTML::WikiConverter::Oddmuse
+
+You can also look for information at:
+
+=over 4
+
+=item * AnnoCPAN: Annotated CPAN documentation
+
+L<http://annocpan.org/dist/HTML-WikiConverter-Oddmuse>
+
+=item * CPAN Ratings
+
+L<http://cpanratings.perl.org/d/HTML-WikiConverter-Oddmuse>
+
+=item * RT: CPAN's request tracker
+
+L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=HTML-WikiConverter-Oddmuse>
+
+=item * Search CPAN
+
+L<http://search.cpan.org/dist/HTML-WikiConverter-Oddmuse>
+
+=back
+
+=head1 COPYRIGHT & LICENSE
+
+Copyright 2006 David J. Iberri, all rights reserved.
+
+This program is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
+
+1;

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/00-load.t
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/00-load.t?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/00-load.t (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/00-load.t Mon Aug  3 08:09:50 2009
@@ -1,0 +1,9 @@
+#!perl -T
+
+use Test::More tests => 1;
+
+BEGIN {
+	use_ok( 'HTML::WikiConverter::Oddmuse' );
+}
+
+diag( "Testing HTML::WikiConverter::Oddmuse $HTML::WikiConverter::Oddmuse::VERSION, Perl $], $^X" );

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/boilerplate.t
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/boilerplate.t?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/boilerplate.t (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/boilerplate.t Mon Aug  3 08:09:50 2009
@@ -1,0 +1,48 @@
+#!perl -T
+
+use strict;
+use warnings;
+use Test::More tests => 3;
+
+sub not_in_file_ok {
+    my ($filename, %regex) = @_;
+    open my $fh, "<", $filename
+        or die "couldn't open $filename for reading: $!";
+
+    my %violated;
+
+    while (my $line = <$fh>) {
+        while (my ($desc, $regex) = each %regex) {
+            if ($line =~ $regex) {
+                push @{$violated{$desc}||=[]}, $.;
+            }
+        }
+    }
+
+    if (%violated) {
+        fail("$filename contains boilerplate text");
+        diag "$_ appears on lines @{$violated{$_}}" for keys %violated;
+    } else {
+        pass("$filename contains no boilerplate text");
+    }
+}
+
+not_in_file_ok(README =>
+    "The README is used..."       => qr/The README is used/,
+    "'version information here'"  => qr/to provide version information/,
+);
+
+not_in_file_ok(Changes =>
+    "placeholder date/time"       => qr(Date/time)
+);
+
+sub module_boilerplate_ok {
+    my ($module) = @_;
+    not_in_file_ok($module =>
+        'the great new $MODULENAME'   => qr/ - The great new /,
+        'boilerplate description'     => qr/Quick summary of what the module/,
+        'stub function definition'    => qr/function[12]/,
+    );
+}
+
+module_boilerplate_ok('lib/HTML/WikiConverter/Oddmuse.pm');

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/oddmuse.t
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/oddmuse.t?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/oddmuse.t (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/oddmuse.t Mon Aug  3 08:09:50 2009
@@ -1,0 +1,230 @@
+local $/;
+require 't/runtests.pl';
+runtests( data => <DATA>, dialect => 'Oddmuse', wiki_uri => 'http://www.test.com/wiki/', camel_case => 1 );
+close DATA;
+
+__DATA__
+bold
+__H__
+<b>bold</b>
+__W__
+*bold*
+__NEXT__
+strong
+__H__
+<strong>strong</strong>
+__W__
+*strong*
+__NEXT__
+italic
+__H__
+<i>italic</i>
+__W__
+/italic/
+__NEXT__
+em
+__H__
+<em>em</em>
+__W__
+~em~
+__NEXT__
+underline
+__H__
+<u>underline</u>
+__W__
+_underline_
+__NEXT__
+image
+__H__
+<img src="http://www.test.com/image.png" />
+__W__
+http://www.test.com/image.png
+__NEXT__
+external link (free link)
+__H__
+<a href="http://www.google.com">http://www.google.com</a>
+__W__
+http://www.google.com
+__NEXT__
+external link (alt text)
+__H__
+<a href="http://www.google.com">Google</a>
+__W__
+[http://www.google.com Google]
+__NEXT__
+internal link
+__H__
+<a href="http://www.test.com/wiki/Markup_Extension">Markup Extension</a>
+__W__
+[[Markup Extension]]
+__NEXT__
+internal link (alt text)
+__H__
+<a href="http://www.test.com/wiki/Markup_Extension">markup ext</a>
+__W__
+[[Markup Extension|markup ext]]
+__NEXT__
+internal link (camel case)
+__H__
+<a href="http://www.test.com/wiki/CamelCaseLink">CamelCaseLink</a>
+__W__
+CamelCaseLink
+__NEXT__
+table
+__H__
+<table>
+<tr><th>foo</th><th>bar</th><th>baz</th></tr>
+<tr><td>one</td><td>two</td><td>three</td></tr>
+<tr><td>1</td><td>2</td><td>3</td></tr>
+</table>
+__W__
+||foo ||bar ||baz ||
+||one ||two ||three ||
+||1 ||2 ||3 ||
+__NEXT__
+table (align)
+__H__
+<table>
+<tr><th align="left">foo</th><th align="center">bar</th><th align="right">baz</th></tr>
+<tr><td align="right">one</td><td align="left">two</td><td align="center">three</td></tr>
+<tr><td align="center">1</td><td align="right">2</td><td align="left">3</td></tr>
+</table>
+__W__
+||foo || bar || baz||
+|| one||two || three ||
+|| 1 || 2||3 ||
+__NEXT__
+table (colspan)
+__H__
+<table>
+<tr><th colspan="2" align="left">foo</th><th align="center">bar</th></tr>
+<tr><td align="right">one</td><td align="left">two</td><td align="center">three</td></tr>
+<tr><td colspan="3" align="center">1</td></tr>
+</table>
+__W__
+||||foo || bar ||
+|| one||two || three ||
+|||||| 1 ||
+__NEXT__
+list (ul)
+__H__
+<ul>
+  <li>one
+  <li>two
+  <li>three
+</ul>
+__W__
+* one
+* two
+* three
+__NEXT__
+list (ol)
+__H__
+<ol>
+  <li>one
+  <li>two
+  <li>three
+</ol>
+__W__
+* one
+* two
+* three
+__NEXT__
+list (nested ul/ul)
+__H__
+<ul>
+  <li>1
+    <ul>
+      <li>1.a
+      <li>1.b
+    </ul>
+  </li>
+  <li>2
+  <li>3
+    <ul>
+      <li>3.a
+      <li>3.b
+    </ul>
+  </li>
+</ul>
+__W__
+* 1
+** 1.a
+** 1.b
+* 2
+* 3
+** 3.a
+** 3.b
+__NEXT__
+list (nested ul/ol)
+__H__
+<ul>
+  <li>1
+    <ol>
+      <li>1.a
+      <li>1.b
+    </ol>
+  </li>
+  <li>2
+  <li>3
+    <ol>
+      <li>3.a
+      <li>3.b
+    </ol>
+  </li>
+</ul>
+__W__
+* 1
+** 1.a
+** 1.b
+* 2
+* 3
+** 3.a
+** 3.b
+__NEXT__
+list (nested ol/ul)
+__H__
+<ol>
+  <li>1
+    <ul>
+      <li>1.a
+      <li>1.b
+    </ul>
+  </li>
+  <li>2
+  <li>3
+    <ul>
+      <li>3.a
+      <li>3.b
+    </ul>
+  </li>
+</ol>
+__W__
+* 1
+** 1.a
+** 1.b
+* 2
+* 3
+** 3.a
+** 3.b
+__NEXT__
+h1..h6
+__H__
+<h1>1</h1>
+<h2>2</h2>
+<h3>3</h3>
+<h4>4</h4>
+<h5>5</h5>
+<h6>6</h6>
+__W__
+=1=
+
+==2==
+
+===3===
+
+====4====
+
+=====5=====
+
+======6======

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod-coverage.t
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod-coverage.t?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod-coverage.t (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod-coverage.t Mon Aug  3 08:09:50 2009
@@ -1,0 +1,25 @@
+#!perl -T
+
+use Test::More;
+eval "use Test::Pod::Coverage 1.04";
+plan skip_all => "Test::Pod::Coverage 1.04 required for testing POD coverage" if $@;
+all_pod_coverage_ok( { also_private => [
+  # These methods are documented in HTML::WikiConverter::Dialects
+  qr/
+     get_elem_contents
+    |get_wiki_page
+    |get_attr_str
+    |is_camel_case
+    |rule
+    |rules
+    |attribute
+    |attributes
+    |preprocess_tree
+    |preprocess_node
+    |postprocess_output
+    |caption2para
+    |strip_aname
+    |base_url
+    |wiki_url
+  /x
+] } );

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod.t
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod.t?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod.t (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/pod.t Mon Aug  3 08:09:50 2009
@@ -1,0 +1,6 @@
+#!perl -T
+
+use Test::More;
+eval "use Test::Pod 1.14";
+plan skip_all => "Test::Pod 1.14 required for testing POD" if $@;
+all_pod_files_ok();

Added: branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/runtests.pl
URL: http://svn.debian.org/wsvn/pkg-perl/branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/runtests.pl?rev=41173&op=file
==============================================================================
--- branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/runtests.pl (added)
+++ branches/upstream/libhtml-wikiconverter-oddmuse-perl/current/t/runtests.pl Mon Aug  3 08:09:50 2009
@@ -1,0 +1,132 @@
+#!/usr/bin/perl
+use warnings;
+use strict;
+
+use Test::More;
+use File::Spec;
+use HTML::Entities;
+use HTML::WikiConverter;
+*e = \&encode_entities;
+
+my $more_tests = <<END_TESTS;
+__NEXT__
+entities (1)
+__H__
+To enter a '&lt;' in your input, use "&amp;lt;"
+__W__
+To enter a '&lt;' in your input, use "&amp;lt;"
+__NEXT__
+entities (2)
+__H__
+To enter a '<' in your input, use "&amp;lt;"
+__W__
+To enter a '&lt;' in your input, use "&amp;lt;"
+__NEXT__
+strip comments
+__H__
+A <!-- stripped --> comment
+__W__
+A  comment
+__NEXT__
+strip head
+__H__
+<html>
+<head><title>fun stuff</title></head>
+<body>
+<p>Crazy stuff here</p>
+</body>
+</html>
+__W__
+Crazy stuff here
+__NEXT__
+strip scripts
+__H__
+<html>
+<head><script>bogus stuff</script></head>
+<body>
+<script>maliciousCode()</script>
+<p>benevolent text</p>
+</body>
+</html>
+__W__
+benevolent text
+END_TESTS
+
+sub runtests {
+  my %arg = @_;
+
+  $arg{wrap_in_html} = 1;
+  $arg{base_uri} ||= 'http://www.test.com';
+  my $minimal = $arg{minimal} || 0;
+
+  my $data = $arg{data} || '';
+  $data .= entity_tests() . $more_tests unless $minimal;
+
+  my @tests = split /__NEXT__\n/, $data;
+  my $numtests = @tests;
+  #$numtests += 1 unless $minimal; # file test
+  plan tests => $numtests;
+
+  # Delete unrecognized HTML::WikiConverter options
+  delete $arg{$_} for qw/ data minimal /;
+
+  my $wc = new HTML::WikiConverter(%arg);
+  foreach my $test ( @tests ) {
+    $test =~ s/^(.*?)\n//; my $name = $1;
+    my( $html, $wiki ) = split /__W__\n/, $test;
+    $html =~ s/__H__\n//;
+
+    $name =~ s{\s*\:\:(\w+\([^\)]*?\))}{
+      my $method_call = $1;
+      eval "\$wc->$method_call;";
+      die "Failed test call ($name): $@" if $@;
+      '';
+    }ge;
+
+    for( $html, $wiki ) { s/^\n+//; s/\n+$// }
+    is( $wc->html2wiki($html), $wiki, $name );
+  }
+
+  #file_test($wc) unless $minimal;
+}
+
+sub entity_tests {
+  my $tmpl = "__NEXT__\n%s\n__H__\n%s\n__W__\n%s\n"; # test-name, html-input, expected-wiki-output
+
+  my $data = '';
+  my @chars = ( '<', '>', '&' );
+  foreach my $char ( @chars ) {
+    ( my $charname = e($char) ) =~ s/[&;]//g;
+    $data .= sprintf $tmpl, "literal ($charname)", $char, e($char)
+          .  sprintf $tmpl, "encode ($charname)", e($char), e($char)
+          .  sprintf $tmpl, "meta ($charname)", e(e($char)), e(e($char));
+  }
+
+  return $data;
+}
+
+sub _slurp {
+  my $path = shift;
+  open H, $path or die "couldn't open $path: $!";
+  local $/;
+  my $c = <H>;
+  close H;
+  return $c;
+}
+
+sub file_test {
+  my $wc = shift;
+  my $lc_dialect = lc $wc->dialect;
+  my $infile = File::Spec->catfile( 't', 'complete.html' );
+  my $outfile = File::Spec->catfile( 't', "complete.$lc_dialect" );
+
+  SKIP: {
+    skip "Couldn't find $infile (ignore this)", 1 unless -e $infile;
+    skip "Couldn't find $outfile (ignore this)", 1 unless -e $outfile;
+    my( $got, $expect ) = ( $wc->html2wiki( file => $infile, slurp => 1 ), _slurp($outfile) );
+    for( $got, $expect ) { s/^\n+//; s/\n+$// }
+    is( $got, $expect, 'read from file' );
+  };
+}
+
+1;




More information about the Pkg-perl-cvs-commits mailing list